63 lines
2.5 KiB
CMake
63 lines
2.5 KiB
CMake
|
# based on the files generated by CMake's write_basic_package_version_file
|
||
|
|
|
||
|
|
# SDL CMake version configuration file:
|
||
|
|
# This file is meant to be placed in share/cmake/SDL3, next to SDL3.xcframework
|
||
|
|
|
||
|
|
cmake_minimum_required(VERSION 3.12)
|
||
|
|
|
||
|
|
get_filename_component(_sdl3_xcframework_parent_path "../.." ABSOLUTE)
|
||
|
|
|
||
|
|
set(_sdl3_xcframework "${_sdl3_xcframework_parent_path}/SDL3.xcframework")
|
||
|
|
set(_sdl3_version_h "${_sdl3_xcframework}/macos-arm64_x86_64/SDL3.framework/Headers/SDL_version.h")
|
||
|
|
|
||
|
|
if(NOT EXISTS "${_sdl3_version_h}")
|
||
|
|
message(AUTHOR_WARNING "Cannot not find SDL_version.h. This script is meant to be placed in share/cmake/SDL3, next to SDL3.xcframework")
|
||
|
|
return()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
file(READ "${_sdl3_version_h}" _sdl_version_h)
|
||
|
|
string(REGEX MATCH "#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_version_h}")
|
||
|
|
set(_sdl_major "${CMAKE_MATCH_1}")
|
||
|
|
string(REGEX MATCH "#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_version_h}")
|
||
|
|
set(_sdl_minor "${CMAKE_MATCH_1}")
|
||
|
|
string(REGEX MATCH "#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_version_h}")
|
||
|
|
set(_sdl_patch "${CMAKE_MATCH_1}")
|
||
|
|
if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
|
||
|
|
set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
|
||
|
|
else()
|
||
|
|
message(AUTHOR_WARNING "Could not extract version from SDL_version.h.")
|
||
|
|
return()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
unset(_sdl3_xcframework)
|
||
|
|
unset(_sdl3_version_h)
|
||
|
|
|
||
|
|
if(PACKAGE_FIND_VERSION_RANGE)
|
||
|
|
# Package version must be in the requested version range
|
||
|
|
if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
|
||
|
|
OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
|
||
|
|
OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
|
||
|
|
set(PACKAGE_VERSION_COMPATIBLE FALSE)
|
||
|
|
else()
|
||
|
|
set(PACKAGE_VERSION_COMPATIBLE TRUE)
|
||
|
|
endif()
|
||
|
|
else()
|
||
|
|
if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
|
||
|
|
set(PACKAGE_VERSION_COMPATIBLE FALSE)
|
||
|
|
else()
|
||
|
|
set(PACKAGE_VERSION_COMPATIBLE TRUE)
|
||
|
|
if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
|
||
|
|
set(PACKAGE_VERSION_EXACT TRUE)
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
# The SDL3.xcframework only contains 64-bit archives
|
||
|
|
if(NOT "${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
|
||
|
|
set(PACKAGE_VERSION_UNSUITABLE TRUE)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(NOT CMAKE_SYSTEM_NAME MATCHES "^(Darwin|iOS|tvOS)$")
|
||
|
|
set(PACKAGE_VERSION_UNSUITABLE TRUE)
|
||
|
|
endif()
|